Lowen fucked around with this message at 03:02 on Feb 9, 2013

Autoexec.bat fucked around with this message at 12:34 on Feb 9, 2013

&lt

Lowen fucked around with this message at 04:08 on Feb 13, 2013

Odysseus S. Grant fucked around with this message at 21:49 on Mar 13, 2013

Haifisch fucked around with this message at 12:51 on Apr 17, 2013

on run
	
	set GBSFMuser to "USERNAME HERE"
	set GBSFMpass to "PASSWORD HERE"
	
	growlsetup()
	
	
	tell application "iTunes"
		set selectedTracks to selection
		
		repeat with thisTrack in selectedTracks
			set trackName to (get artist of thisTrack as string) & " - " & (get name of thisTrack as string)
			set thisTrackPath to quote & (POSIX path of (get location of thisTrack as alias) as string) & quote
			set trackKind to kind of thisTrack as string
			
			if trackKind is not "MPEG audio file" then
				tell application id "com.Growl.GrowlHelperApp"
					notify with name ¬
						"Converting" title ¬
						"Converting to MP3" description ¬
						trackName application name "Upload to GBS-FM"
				end tell
				
				set outputFile to quote & "/tmp/" & trackName & ".mp3" & quote
				do shell script "source ~/.bash_profile;ffmpeg -i " & thisTrackPath & " -f mp3 -ar 44100 -ab 320k -ac 2 " & outputFile
				set thisTrackPath to outputFile
			end if
			
			tell application id "com.Growl.GrowlHelperApp"
				notify with name ¬
					"Uploading" title ¬
					"Uploading to GBS-FM" description ¬
					trackName application name "Upload to GBS-FM"
			end tell
			
			do shell script "curl -T " & thisTrackPath & " ftp://gbs.fm:2100 --user " & GBSFMuser & ":" & GBSFMpass
			if trackKind is not "MPEG audio file" then
				do shell script "rm " & thisTrackPath
			end if
			
			tell application id "com.Growl.GrowlHelperApp"
				notify with name ¬
					"Finished" title ¬
					"Finished uploading to GBS-FM" description ¬
					trackName application name "Upload to GBS-FM"
			end tell
		end repeat
	end tell
end run

on growlsetup()
	--Check if Growl is running
	tell application "System Events"
		set isRunning to (count of (every process whose bundle identifier is "com.Growl.GrowlHelperApp")) > 0
	end tell
	
	if isRunning then
		tell application id "com.Growl.GrowlHelperApp"
			set the allNotificationsList to ¬
				{"Uploading", "Finished", "Converting"}
			
			set the enabledNotificationsList to ¬
				{"Uploading", "Finished", "Converting"}
			
			register as application ¬
				"Upload to GBS-FM" all notifications allNotificationsList ¬
				default notifications enabledNotificationsList ¬
				icon of application "AppleScript Editor"
		end tell
	end if
end growlsetup

ElBob fucked around with this message at 05:36 on May 20, 2013