code:

tell application "iTunes"
	
	set start_time to (current date)
	set currentList to view of front window
	
	
	with timeout of 30000 seconds
		try
			set unplayedTracks to (every track of currentList whose played count is 0)
		on error n
			display dialog (n & return & return & "My advice: Select another Playlist.")
			return
		end try
	end timeout
	
	if unplayedTracks is {} then
		try
			set playedTracks to {played date of every track of currentList whose played count is not 0, database ID of every track of currentList whose played count is not 0}
		on error n
			display dialog (n & return & return & "My advice: Select another Playlist.")
			return
		end try
		
		set trackToPlayID to my findOldestTrack(playedTracks)
		
	else
		set trackToPlayID to (database ID of item (random number from 1 to number of items in unplayedTracks) of unplayedTracks)
	end if
	
	with timeout of 30000 seconds
		try
			play (some track of currentList whose database ID is trackToPlayID)
		on error n
			display dialog (n & return & return & "Usually this means the file is missing.")
			return
		end try
	end timeout
	
	set run_time to ((current date) - start_time)
	return run_time
	
end tell

on findOldestTrack(inputList)
	
	set checkDate to item 1 of item 1 of inputList
	
	repeat with x from 2 to (number of items in item 1 of inputList)
		set xDate to (item x of item 1 of inputList)
		if xDate < checkDate then
			set checkDate to xDate
			set oldestTrackID to (item x of item 2 of inputList)
		end if
	end repeat
	
	return oldestTrackID
	
end findOldestTrack