code:

@echo off
sqlite3.exe -version > nul || goto Nevermind

REM Find Firefox directory and set variables
for /d %%a in ("%appdata%\Mozilla\Firefox\Profiles\*") do set ffprofile=%%a
for %%I in (%ffprofile%\places.sqlite) do set ffplaces=%%~zI

REM Back-up places.sqlite
if exist %ffprofile%\places.sqlite.bak goto Allbackedup
echo Backing-up database
copy %ffprofile%\places.sqlite %ffprofile%\places.sqlite.bak
:Allbackedup
echo Back-up file exists

REM Clear redundant or unwanted pages from Firefox history and superbar.
REM List phrases to match webpage titles to be removed line-by-line in clear_title.txt and
REM List partial URLs to match URLs to be removed line-by-line in clear_url.txt
echo Removing file-specified entries...
if exist clear_url.txt for /f "delims=" %%a IN (clear_url.txt) DO ^
sqlite3 %ffprofile%\places.sqlite "delete from moz_places where url like '%%%%a%%';"
if not exist clear_url.txt echo Clear_url.txt does not exist.
if exist clear_title.txt for /f "delims=" %%a IN (clear_title.txt) DO ^
sqlite3 %ffprofile%\places.sqlite "delete from moz_places where title like '%%%%a%%';"
if not exist clear_title.txt echo Clear_title.txt does not exist.

REM Compact Firefox sqlite files
echo Compacting database files...
for %%a in (%ffprofile%\*.sqlite) do sqlite3 %%a vacuum

REM Pause to check the size, then bye
dir %ffprofile%\places.sqlite
echo This is the size of the main database file, now.
for %%I in (%ffprofile%\places.sqlite) do set /a ffplaces=%ffplaces%-%%~zI
echo It is %ffplaces% bytes smaller now than before cleaning it
pause
echo on

@exit /b

:Nevermind
REM  If you don't have sqlite3.exe
echo Get sqlite3.exe and try this again
echo on